Elkarrizketetan oinarritzen diren programen ebazpidea
Elkarrizketek garrantzi handia duteneko programak ugariak dira irakaskuntzan. Eta gaur, hemen planteiatzen den programa hau, horietako bat da. Bestalde, azalpen hau egiterakoan gure asmoa, ez da mota hauetako programei zehaztasunez erantzutea izan (nahiz eta horretarako kasu konkretu batean oinarritu); mota hauetako programen aurrean nola joka daitekeen agertzea baizik.
Beraz eta zerorrek, irakurle, baieztatzeko aukera izango duzunez, hemen planteiatzen den programaren ebazpena nahiko erraza eta ulerkorra da. Ordenadoreak erradioa eta beharrezkoa baldin bada, altuera ere eskatuko digu. Ondorenean, eta aurrez emandako aginduen arabera, esfera, kono edo zilindro baten bolumena kalkulatuko du, emaitza adieraziz.
Hona hemen, argibide gisa, programa honen organigrama:
10 REM ** ELKARRIZKETA-PROGRAMA **
20 CLS
30 LET PI=3.141592
40 PRINT "Programa honen bidez esfera, kono edo zilindroen bolumenak kalkulatzen dira"
50 FOR T = 1 TO 1200
60 I = I + 1
70 NEXT T
80 CLS
90 PRINT
100 PRINT "Kalkulatu nahi duzun bolumena zein motatako irudiari dagokio?"
110 PRINT
120 PRINT "Esferarena baldin bada, ipini 1 zenbakia"
130 PRINT "Konoarena baldin bada, ipini 2 zenbakia"
140 PRINT "Zilindroarena baldin bada, ipini 3 zenbakia"
150 INPUT A
160 IF A = 1 THEN GOSUB 200: GOTO 430
170 IF A = 2 THEN GOSUB 270: GOTO 430
180 IF A = 3 THEN GOSUB 350: GOTO 430
190 GOTO 80
200 REM ** Esferaren bolumena **
210 CLS : PRINT "Esferaren bolumena honako hau da: V = 4 * PI * R ^ 3/3"
220 INPUT "Zenbat balio du esferaren erradioak"; R
230 LET V = 4 * PI * R ^ 3/3
240 PRINT : PRINT "Esferaren bolumena: V ="; V
250 RETURN
260 REM ** Esferaren bolumenaren amaia **
270 REM ** Konoaren bolumena **
280 CLS : PRINT "Konoaren bolumena honako hau da: V = PI * R ^ 2 * H/3"
290 INPUT "Zenbat balio du konoaren oinaren erradioak"; R
300 INPUT "Eta konoaren altuerak"; H
310 LET V = PI * R ^ 2 * H/3
320 PRINT "Konoaren bolumena: V ="; V
330 RETURN
340 REM ** Konoaren bolumenaren amaia **
350 REM ** Zilindroaren bolumena **
360 CLS : PRINT "Zilindroaren bolumena honako hau da: V = PI * R ^ 2 * H"
370 INPUT "Zenbat balio du zilindroaren oinaren erradioak"; R
380 INPUT "Eta zilindroaren altuerak"; H
390 LET V = PI * R ^ 2 * H
400 PRINT "Zilindroaren bolumena: V ="; V
410 RETURN
420 REM ** Zilindroaren bolumenaren amaia **
430 INPUT "Beste bolumenik kalkulatu nahi (BAI/EZ)"; C$
440 IF C$ = "BAI" OR C$ = "bai" THEN GOTO 20
450 IF C$ = "EZ" OR C$ = "ez" THEN 470
460 GOTO 430
470 CLS
480 PRINT : PRINT : PRINT
490 PRINT "Erraza ezta?. Antzeko programaren bat burutzen ahalegindu, agur."
500 END
Zu idazle
Zientzia aldizkaria
